1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
|
/*
* Copyright 2013 Canonical Ltd.
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; version 3.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU Lesser General Public License for more details.
*
* You should have received a copy of the GNU Lesser General Public License
* along with this program. If not, see <http://www.gnu.org/licenses/>.
*
* Authors:
* Lars Uebernickel <lars.uebernickel@canonical.com>
*/
/**
* MediaPlayerList is a list of media players that should appear in the sound menu. Its main responsibility is
* to listen for MPRIS players on the bus and attach them to the corresponding %Player objects.
*/
public class MediaPlayerList {
public MediaPlayerList () {
this._players = new HashTable<string, MediaPlayer> (str_hash, str_equal);
BusWatcher.watch_namespace (BusType.SESSION, "org.mpris.MediaPlayer2", this.player_appeared, this.player_disappeared);
}
/* only valid while the list is not changed */
public class Iterator {
HashTableIter<string, MediaPlayer> iter;
public Iterator (MediaPlayerList list) {
this.iter = HashTableIter<string, MediaPlayer> (list._players);
}
public MediaPlayer? next_value () {
MediaPlayer? player;
if (this.iter.next (null, out player))
return player;
else
return null;
}
}
public Iterator iterator () {
return new Iterator (this);
}
/**
* Adds the player associated with @desktop_id. Does nothing if such a player already exists.
*/
MediaPlayer? insert (string desktop_id) {
var id = desktop_id.has_suffix (".desktop") ? desktop_id : desktop_id + ".desktop";
MediaPlayer? player = this._players.lookup (id);
if (player == null) {
var appinfo = new DesktopAppInfo (id);
if (appinfo == null) {
warning ("unable to find application '%s'", id);
return null;
}
player = new MediaPlayer (appinfo);
this._players.insert (player.id, player);
this.player_added (player);
}
return player;
}
/**
* Removes the player associated with @desktop_id, unless it is currently running.
*/
void remove (string desktop_id) {
MediaPlayer? player = this._players.lookup (desktop_id);
if (player != null && !player.is_running) {
this._players.remove (desktop_id);
this.player_removed (player);
}
}
/**
* Synchronizes the player list with @desktop_ids. After this call, this list will only contain the players
* in @desktop_ids. Players that were running but are not in @desktop_ids will remain in the list.
*/
public void sync (string[] desktop_ids) {
/* hash desktop_ids for faster lookup */
var hash = new HashTable<string, unowned string> (str_hash, str_equal);
foreach (var id in desktop_ids)
hash.add (id);
/* remove players that are not desktop_ids */
foreach (var id in this._players.get_keys ()) {
if (!hash.contains (id))
this.remove (id);
}
/* insert all players (insert() takes care of not adding a player twice */
foreach (var id in desktop_ids)
this.insert (id);
}
public signal void player_added (MediaPlayer player);
public signal void player_removed (MediaPlayer player);
HashTable<string, MediaPlayer> _players;
void player_appeared (DBusConnection connection, string name, string owner) {
try {
MprisRoot mpris2_root = Bus.get_proxy_sync (BusType.SESSION, name, MPRIS_MEDIA_PLAYER_PATH);
var player = this.insert (mpris2_root.DesktopEntry);
if (player != null)
player.attach (name);
}
catch (Error e) {
warning ("unable to create mpris proxy for '%s': %s", name, e.message);
}
}
void player_disappeared (DBusConnection connection, string dbus_name) {
MediaPlayer? player = this._players.find ( (name, player) => {
return player.dbus_name == dbus_name;
});
if (player != null)
player.detach ();
}
}
|
