From 4d74e36f359d22b50302c82a922b79ac24dd3e23 Mon Sep 17 00:00:00 2001
From: marha <marha@users.sourceforge.net>
Date: Tue, 14 Jun 2011 08:12:46 +0200
Subject: libxcb mesa xkeyboard-config git update 14 June 2011

---
 xorg-server/xkeyboard-config/man/Makefile.am |  17 ++++
 xorg-server/xkeyboard-config/man/man.xsl     | 137 +++++++++++++++++++++++++++
 2 files changed, 154 insertions(+)
 create mode 100644 xorg-server/xkeyboard-config/man/Makefile.am
 create mode 100644 xorg-server/xkeyboard-config/man/man.xsl

(limited to 'xorg-server/xkeyboard-config/man')

diff --git a/xorg-server/xkeyboard-config/man/Makefile.am b/xorg-server/xkeyboard-config/man/Makefile.am
new file mode 100644
index 000000000..2e9deaa48
--- /dev/null
+++ b/xorg-server/xkeyboard-config/man/Makefile.am
@@ -0,0 +1,17 @@
+EXTRA_DIST = man.xsl
+
+if HAVE_XSLTPROC
+miscmandir = $(MISC_MAN_DIR)
+miscman_PRE = xkeyboard-config.man
+miscman_DATA = $(miscman_PRE:man=@MISC_MAN_SUFFIX@)
+CLEANFILES = $(miscman_DATA) $(miscman_PRE)
+SUFFIXES = .$(MISC_MAN_SUFFIX) .man
+MAN_SUBSTS += -e 's|__xkb_base__|$(xkb_base)|g'
+
+xkeyboard-config.man: $(top_builddir)/rules/evdev.xml $(srcdir)/man.xsl
+	$(XSLTPROC) -nonet $(srcdir)/man.xsl $(top_builddir)/rules/evdev.xml > $@
+
+.man.$(MISC_MAN_SUFFIX):
+	$(SED) $(MAN_SUBSTS) < $< > $@
+
+endif
diff --git a/xorg-server/xkeyboard-config/man/man.xsl b/xorg-server/xkeyboard-config/man/man.xsl
new file mode 100644
index 000000000..a5bd14d01
--- /dev/null
+++ b/xorg-server/xkeyboard-config/man/man.xsl
@@ -0,0 +1,137 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
+    <xsl:output method="text" encoding="UTF-8" doctype-system="xkb.dtd"/>
+    <xsl:template match="/xkbConfigRegistry">
+        <xsl:text><![CDATA[.\" WARNING: this man page is autogenerated. Do not edit or you will lose all your changes.
+.TH XKEYBOARD-CONFIG __miscmansuffix__ __vendorversion__
+.SH NAME
+xkeyboard-config \- XKB data description files
+.SH DESCRIPTION
+xkeyboard-config provides the description files for the X Keyboard
+Extension (XKB). The configuration options below are usually applied with
+setxkbmap(__appmansuffix__).
+.SH MODELS
+.TS
+left,box;
+lB lB
+___
+lB l.
+Model	Description
+]]></xsl:text>
+        <xsl:apply-templates select="modelList"/>
+        <xsl:text><![CDATA[
+.TE
+.SH LAYOUTS
+.TS
+left,box;
+lB lB
+____
+lB l.
+Layout(Variant)	Description
+]]></xsl:text>
+        <xsl:apply-templates select="layoutList"/>
+        <xsl:text><![CDATA[
+.TE
+.SH OPTIONS
+]]></xsl:text>
+        <xsl:apply-templates select="optionList"/>
+        <xsl:text><![CDATA[
+.SH FILES
+__xkb_base__/compat
+
+__xkb_base__/compiled
+
+__xkb_base__/geometry
+
+__xkb_base__/keycodes
+
+__xkb_base__/keymap
+
+__xkb_base__/rules
+
+__xkb_base__/semantics
+
+__xkb_base__/symbols
+
+__xkb_base__/types
+
+.SH SEE ALSO
+setxkbmap(__appmansuffix__)
+]]></xsl:text>
+    </xsl:template>
+
+<!-- split model/description into a normal table -->
+    <xsl:template match="modelList">
+        <xsl:for-each select="model">
+            <xsl:value-of select="configItem/name"/><xsl:text>&#9;</xsl:text><xsl:value-of select="configItem/description"/>
+            <xsl:text>&#10;</xsl:text>
+        </xsl:for-each>
+    </xsl:template>
+
+<!-- split layout/variant/description into a table like this
+
+        layout1                 description
+        layout1(variant1)       description
+        layout1(variant2)       description
+        layout2                 description
+        layout2(variant1)       description
+-->
+    <xsl:template match="layoutList">
+        <xsl:for-each select="layout">
+            <xsl:value-of select="configItem/name"/>
+            <xsl:text>&#9;</xsl:text>
+            <xsl:value-of select="configItem/description"/>
+            <xsl:text>&#10;</xsl:text>
+            <xsl:for-each select="variantList/variant">
+                <xsl:value-of select="../../configItem/name"/>
+                <xsl:text>(</xsl:text>
+                <xsl:value-of select="configItem/name"/>
+                <xsl:text>)</xsl:text>
+                <xsl:text>&#9;</xsl:text>
+                <xsl:value-of select="configItem/description"/>
+                <xsl:text>&#10;</xsl:text>
+            </xsl:for-each>
+            <xsl:text>&#10;</xsl:text>
+            <xsl:text>_&#10;</xsl:text>
+        </xsl:for-each>
+    </xsl:template>
+
+<!-- split option into a table like this
+
+option description:
+        optarg          description
+        optarg          description
+        optarg          description
+
+option2 description:
+        optarg          description
+        optarg          description
+-->
+    <xsl:template match="optionList">
+        <xsl:for-each select="group">
+            <xsl:text><![CDATA[
+.SS]]></xsl:text>
+            <xsl:text>&#10;</xsl:text>
+            <xsl:value-of select="configItem/description"/>
+            <xsl:text><![CDATA[
+.BR
+.TS
+left,box;
+lB lB
+___
+lB l.
+Option	Description
+]]></xsl:text>
+            <xsl:for-each select="option">
+                <xsl:value-of select="configItem/name"/>
+                <xsl:text>&#9;</xsl:text>
+                <xsl:value-of select="configItem/description"/>
+                <xsl:text>&#10;</xsl:text>
+            </xsl:for-each>
+            <xsl:text><![CDATA[
+.TE
+
+]]></xsl:text>
+        </xsl:for-each>
+    </xsl:template>
+</xsl:stylesheet>
-- 
cgit v1.2.3