1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
|
; example2.nsi
;
; This script is based on example1.nsi, but it remember the directory,
; has uninstall support and (optionally) installs start menu shortcuts.
;
; It will install example2.nsi into a directory that the user selects,
;--------------------------------
; The name of the installer
Name "VcXsrv"
; The file to write
OutFile "vcxsrv.1.7.99.3.installer.exe"
; The default installation directory
InstallDir $PROGRAMFILES\VcXsrv
; Registry key to check for directory (so if you install again, it will
; overwrite the old one automatically)
InstallDirRegKey HKLM "Software\VcXsrv" "Install_Dir"
; Request application privileges for Windows Vista
RequestExecutionLevel admin
;--------------------------------
InstType "Full"
InstType "Minimal"
; Pages
Page components
Page directory
Page instfiles
UninstPage uninstConfirm
UninstPage instfiles
SetPluginUnload alwaysoff
; ShowInstDetails show
XPStyle on
!define FUSION_REFCOUNT_UNINSTALL_SUBKEY_GUID {8cedc215-ac4b-488b-93c0-a50a49cb2fb8}
!include runtime
;--------------------------------
; The stuff to install
Section "VcXsrv (required)"
SectionIn RO
SectionIn 1 2
; Set output path to the installation directory.
SetOutPath $INSTDIR
; Put files there
File "..\obj\servrelease\vcxsrv.exe"
File "..\obj\servdebug\vcxsrv_dbg.exe"
File "..\obj\servdebug\vcxsrv_dbg.pdb"
File "..\protocol.txt"
File "..\system.XWinrc"
File "..\..\xkbcomp\obj\release\xkbcomp.exe"
File "..\..\apps\xcalc\obj\release\xcalc.exe"
File "..\xcalc"
File "..\xcalc-color"
File "..\..\apps\xclock\obj\release\xclock.exe"
File "..\..\apps\xwininfo\obj\release\xwininfo.exe"
File "..\XKeysymDB"
File "..\XErrorDB"
File "..\hw\xwin\xlaunch\obj\release\xlaunch.exe"
File "..\..\tools\plink\obj\release\plink.exe"
File "..\..\mesalib\windows\VC8\mesa\Release\opengl32.dll"
File "..\..\mesalib\windows\VC8\mesa\Release\swrast_dri.dll"
SetOutPath $INSTDIR\fonts
File /r "..\fonts\*.*"
SetOutPath $INSTDIR\xkbdata
File /r "..\xkbdata\*.*"
SetOutPath $INSTDIR\locale
File /r "..\locale\*.*"
; Write the installation path into the registry
WriteRegStr HKLM SOFTWARE\VcXsrv "Install_Dir" "$INSTDIR"
; Write the uninstall keys for Windows
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VcXsrv" "DisplayName" "VcXsrv"
WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VcXsrv" "UninstallString" '"$INSTDIR\uninstall.exe"'
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VcXsrv" "NoModify" 1
WriteRegDWORD HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VcXsrv" "NoRepair" 1
WriteUninstaller "uninstall.exe"
; Register the xlaunch file extension
WriteRegStr HKCR ".xlaunch" "" "XLaunchFile"
WriteRegStr HKCR "XLaunchFile" "" "XLaunch Configuration"
WriteRegStr HKCR "XLaunchFile\DefaultIcon" "" "$INSTDIR\xlaunch.exe,0"
WriteRegStr HKCR "XLaunchFile\shell\open\command" "" '"$INSTDIR\XLaunch.exe" -run "%1"'
WriteRegStr HKCR "XLaunchFile\shell\open\ddeexec\Application" "" "XLaunch"
WriteRegStr HKCR "XLaunchFile\shell\open\ddeexec\Topic" "" "System"
WriteRegStr HKCR "XLaunchFile\shell\edit\command" "" '"$INSTDIR\XLaunch.exe" -load "%1"'
WriteRegStr HKCR "XLaunchFile\shell\edit\ddeexec\Application" "" "XLaunch"
WriteRegStr HKCR "XLaunchFile\shell\edit\ddeexec\Topic" "" "System"
WriteRegStr HKCR "XLaunchFile\shell\Validate\command" "" '"$INSTDIR\XLaunch.exe" -validate "%1"'
WriteRegStr HKCR "XLaunchFile\shell\Validate\ddeexec\Application" "" "XLaunch"
WriteRegStr HKCR "XLaunchFile\shell\Validate\ddeexec\Topic" "" "System"
InitPluginsDir
SetOutPath $PLUGINSDIR
File "${MSVCR90_DLL}"
File "${MSVCM90_DLL}"
File "${MSVCP90_DLL}"
File "${MSVC_CAT}"
File "${MSVC_MANIFEST}"
File "${MSVCR90_DLL_D}"
File "${MSVCM90_DLL_D}"
File "${MSVCP90_DLL_D}"
File "${MSVC_CAT_D}"
File "${MSVC_MANIFEST_D}"
DetailPrint "Installing CRT assembly..."
System::Call "sxs::CreateAssemblyCache(*i .r0, i 0) i.r1"
StrCmp $1 0 0 fail
# Fill a FUSION_INSTALL_REFERENCE.
# fir.cbSize = sizeof(FUSION_INSTALL_REFERENCE) == 32
# fir.dwFlags = 0
# fir.guidScheme = FUSION_REFCOUNT_UNINSTALL_SUBKEY_GUID
# fir.szIdentifier = "nsissxs"
# fir.szNonCanonicalData = 0
System::Call "*(i 32, i 0, i 2364391957, i 1217113163, i 178634899, i 3090139977, w 'nsissxs', w '') i.s"
Pop $2
# IAssemblyCache::InstallAssembly(0, manifestPath, fir)
System::Call "$0->7(i 0, w '$PLUGINSDIR\${MSVC_MANIFEST_PART}', i r2) i.r1"
System::Call "$0->7(i 0, w '$PLUGINSDIR\${MSVC_MANIFEST_PART_D}', i r2) i.r1"
System::Free $2
StrCmp $1 0 0 fail2
System::Call "$0->2()"
Goto end
fail:
DetailPrint "CreateAssemblyCache failed."
DetailPrint $1
Goto end
fail2:
DetailPrint "InstallAssembly failed."
DetailPrint $1
Goto end
end:
SectionEnd
; Optional section (can be disabled by the user)
Section "Start Menu Shortcuts"
SectionIn 1
SetOutPath $INSTDIR
CreateDirectory "$SMPROGRAMS\VcXsrv"
CreateShortCut "$SMPROGRAMS\VcXsrv\Uninstall VcXsrv.lnk" "$INSTDIR\uninstall.exe" "" "$INSTDIR\uninstall.exe" 0
CreateShortCut "$SMPROGRAMS\VcXsrv\VcXsrv.lnk" "$INSTDIR\vcxsrv.exe" " :1 -ac -terminate -lesspointer -multiwindow -clipboard +kb" "$INSTDIR\vcxsrv.exe" 0
CreateShortCut "$SMPROGRAMS\VcXsrv\XLaunch.lnk" "$INSTDIR\xlaunch.exe" "" "$INSTDIR\xlaunch.exe" 0
SectionEnd
; Optional section (can be disabled by the user)
Section "Desktop Shortcuts"
SectionIn 1
SetOutPath $INSTDIR
CreateShortCut "$DESKTOP\VcXsrv.lnk" "$INSTDIR\vcxsrv.exe" " :1 -ac -terminate -lesspointer -multiwindow -clipboard +kb" "$INSTDIR\vcxsrv.exe" 0
CreateShortCut "$DESKTOP\XLaunch.lnk" "$INSTDIR\xlaunch.exe" "" "$INSTDIR\xlaunch.exe" 0
SectionEnd
;--------------------------------
; Uninstaller
Section "Uninstall"
; Remove registry keys
DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\VcXsrv"
DeleteRegKey HKLM SOFTWARE\VcXsrv
; Register the xlaunch file extension
DeleteRegKey HKCR ".xlaunch"
DeleteRegKey HKCR "XLaunchFile"
; Remove files and uninstaller
Delete "$INSTDIR\vcxsrv.exe"
Delete "$INSTDIR\uninstall.exe"
Delete "$INSTDIR\protocol.txt"
Delete "$INSTDIR\system.XWinrc"
Delete "$INSTDIR\xkbcomp.exe"
Delete "$INSTDIR\XKeysymDB"
Delete "$INSTDIR\XErrorDB"
Delete "$INSTDIR\xlaunch.exe"
RMDir /r "$INSTDIR\fonts"
RMDir /r "$INSTDIR\xkbdata"
RMDir /r "$INSTDIR\locale"
; Remove shortcuts, if any
Delete "$SMPROGRAMS\VcXsrv\*.*"
Delete "$DESKTOP\VcXsrv.lnk"
Delete "$DESKTOP\XLaunch.lnk"
; Remove directories used
RMDir "$SMPROGRAMS\VcXsrv"
RMDir "$INSTDIR"
DetailPrint "Removing CRT assembly..."
System::Call "sxs::CreateAssemblyCache(*i .r0, i 0) i.r1"
StrCmp $1 0 0 fail
System::Call "*(i 32, i 0, i 2364391957, i 1217113163, i 178634899, i 3090139977, w 'nsissxs', w '') i.s"
Pop $2
System::Call "$0->3(i 0, w 'Microsoft.VC90.CRT,version=$\"9.0.${MSVC_VERSION}$\",type=$\"win32$\",processorArchitecture=$\"x86$\",publicKeyToken=$\"${MSVC_PUBLICTOKEN}$\"', i r2, *i . r3) i.r1"
System::Call "$0->3(i 0, w 'Microsoft.VC90.DebugCRT,version=$\"9.0.${MSVC_VERSION_D}$\",type=$\"win32$\",processorArchitecture=$\"x86$\",publicKeyToken=$\"${MSVC_PUBLICTOKEN}$\"', i r2, *i . r3) i.r1"
StrCmp $1 0 0 fail2
DetailPrint "Disposition returned is $3"
System::Call "$0->2()"
Goto end
fail:
DetailPrint "CreateAssemblyCache failed."
DetailPrint $1
Goto end
fail2:
DetailPrint "UninstallAssembly failed."
DetailPrint $1
Goto end
end:
SectionEnd
|
